The Coldfusion Open Source Software Blog

Value Object Generator

2008-03-07T10:11:00-07:00

I wrote a little CFM file to generate actionscript classes for value objects from coldfusion queries. It uses getMetaData() on the query to determine data types for the VO. I've only coded in some simple datatypes in the getColType() method to handle the conversion from the dbtype to actionscript data type - you can add whatever you need.

<cfquery name="qry" datasource="ENQUIRE" maxrows="1">
select
  A.QUERYID, A.USERID, A.QUERYDATE, A.INSTANCE,
  A.TITLE, A.SAVED, A.LASTRUNDATE,
  A.CRITERIA
from dbo.DROP_QUERIES A
where
  A.USERID=<cfqueryparam cfsqltype="cf_sql_char" value="ADSRJR">
  AND A.SAVED=<cfqueryparam cfsqltype="cf_sql_smallint" value="1">
order by
  A.QUERYDATE desc
</cfquery>

<cfoutput><pre>
/////////////////////////////////////////////////////
// #voName#.as
//
// generated by voGenerator.cfm (Rick Root)
// generated on #dateFormat(Now(),'yyyy-mm-dd')# at #TimeFormat(Now(),'h:mm tt')#
//
//
/////////////////////////////////////////////////////

package #voPackage#
{
[RemoteClass(alias="#remoteClass#")]
public class #voName#
{
</cfoutput>
<cfset metadata = getMetaData(qry)>
<cfloop from="1" to="#ArrayLen(metadata)#" step="1" index="x">
<cfoutput> private var _#metadata[x].Name#: #getColType(metadata[x].TypeName)#;#chr(10)#</cfoutput>
</cfloop>

<cfloop from="1" to="#ArrayLen(metadata)#" step="1" index="x">
<cfoutput>
  public function get #metadata[x].Name#(): #getColType(metadata[x].TypeName)#
  {
   return _#metadata[x].Name#;
  }

  public function set #metadata[x].Name#(value:#getColType(metadata[x].TypeName)#): void
  {
   _#metadata[x].Name# = value;
  }

</cfoutput>
</cfloop>
<cfoutput>
public function #voName#()
{

}
}
}
</pre>
</cfoutput>

Here is an example of the value object generated from the code above:

/////////////////////////////////////////////////////
// EntityLogVO.as
//
// generated by voGenerator.cfm (Rick Root)
// generated on 2008-03-07 at 12:40 PM
//
//
/////////////////////////////////////////////////////

package model.vo
{
[RemoteClass(alias="cfcs.enquire.vo.EntityLogVO")]
public class EntityLogVO
{
  private var _QUERYID: int;
  private var _USERID: String;
  private var _QUERYDATE: Date;
  private var _INSTANCE: String;
  private var _TITLE: String;
  private var _SAVED: int;
  private var _LASTRUNDATE: Date;
  private var _CRITERIA: String;

  public function get QUERYID(): int
  {
   return _QUERYID;
  }

  public function set QUERYID(value:int): void
  {
   _QUERYID = value;
  }

  public function get USERID(): String
  {
   return _USERID;
  }

  public function set USERID(value:String): void
  {
   _USERID = value;
  }

  public function get QUERYDATE(): Date
  {
   return _QUERYDATE;
  }

  public function set QUERYDATE(value:Date): void
  {
   _QUERYDATE = value;
  }

  public function get INSTANCE(): String
  {
   return _INSTANCE;
  }

  public function set INSTANCE(value:String): void
  {
   _INSTANCE = value;
  }

  public function get TITLE(): String
  {
   return _TITLE;
  }

  public function set TITLE(value:String): void
  {
   _TITLE = value;
  }

  public function get SAVED(): int
  {
   return _SAVED;
  }

  public function set SAVED(value:int): void
  {
   _SAVED = value;
  }

  public function get LASTRUNDATE(): Date
  {
   return _LASTRUNDATE;
  }

  public function set LASTRUNDATE(value:Date): void
  {
   _LASTRUNDATE = value;
  }

  public function get CRITERIA(): String
  {
   return _CRITERIA;
  }

  public function set CRITERIA(value:String): void
  {
   _CRITERIA = value;
  }

public function EntityLogVO()
{

}
}
}

AIR Url - Adobe AIR Project

2007-08-15T09:06:34-07:00

The Adobe on AIR bus tour is stopping by the Raleigh area on Saturday, courtesy of TACFUG and RDAUG, and they're having a contest. Best AIR app wins a prize!

Well, my url shortener app may not be the best, but if I'm lucky, it'll be the only app submitted.

I've recompiled the URL shortener app as an AIR app (I built it when it was still called Apollo), and you can get it here:

AIR Url Installer - AIRUrl.air

Here's the source code:

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication
xmlns:mx="http://www.adobe.com/2006/mxml"
layout="absolute"
width="400" height="68"
creationComplete="init()">
<mx:Script>
<![CDATA[
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.Fault;
import mx.controls.Alert;

import mx.utils.StringUtil;

private function init():void {
txtLongUrl.setFocus();
}
private function genericFault(e:FaultEvent):void
{
txtShortUrl.text = e.fault.faultString;
btnTryIt.enabled = false;
}
private function tryUrl(url:String):void {
navigateToURL(new URLRequest(url), '_blank');
}
private function addUrlResult(e:ResultEvent):void {
txtLongUrl.text = '';
txtShortUrl.text = e.result.toString();
if (e.result.toString() != 'Invalid Source URL!') {
  btnTryIt.enabled = true;
}
}
]]>
</mx:Script>
<mx:WebService id="ro" wsdl="http://url.rickroot.com/url.cfc?wsdl" showBusyCursor="true">
  <mx:operation name="addUrl" fault="genericFault(event)" result="addUrlResult(event)"/>
</mx:WebService>
<mx:VBox x="10" y="10">
  <mx:HBox>
   <mx:Label text="Url to Shorten:" width="100" fontWeight="bold"/>
   <mx:TextInput id="txtLongUrl" width="200"/>
   <mx:Button id="btnDoIt" label="Do It!" click="txtShortUrl.text = ''; ro.addUrl(txtLongUrl.text);"/>
  </mx:HBox>
  <mx:HBox>
   <mx:Label text="Results:" width="100" fontWeight="bold"/>
   <mx:TextInput id="txtShortUrl" width="200"/>
   <mx:Button id="btnTryIt" label="Try It!" click="tryUrl(txtShortUrl.text);" enabled="false"/>
  </mx:HBox>
</mx:VBox>
</mx:WindowedApplication>

ImageCFC 2.16 Now Available

2007-05-31T08:48:59-07:00

ImageCFC Project Page: http://www.opensourcecf.com/imagecfc/

I released ImageCFC 2.15 yesterday without testing it.

Today, I released ImageCFC 2.16 *AFTER* testing it. Not heavily, but I did run at least one test of every method. I also included my simple test file, "test-cases.cfm"

If you haven't gotten ImageCFC lately, you should definately update! If you're using a recent version of ImageCFC, you should be able to just drop the code in place without changing YOUR code. ImageCFC 2.15 and 2.16 only included changes to the main "image.cfc" file.

See the CHANGELOG for details.

My First Apollo Application

2007-05-11T14:37:24-07:00

okay, it's really my second apollo application. But it seemed silly for my first apollo blog entry here to say "My second apollo application" when I never mentioned the first one. Plus, the first one is really an internal app for my job that serves no purpose outside my department.

Anyway, if you participate in a lot of mailing lists, then you probably use tinyurl a lot. Need a shorten a URL, load up www.tinyurl.com, paste in your url, and submit. It returns a nice "tiny url" for you.

Well now you can have a little flex app running all the time called "My Url Shortener" that does the same thing, without having to launch a browser. Just keep it running.. put it in your startup or something like that.

To run this application, you'll first need to install the Apollo Runtime from Adobe, then get the MyUrlShortener installer and run it.

If you'd like the source, which includes the mxml, cfc, and cfm files, along with a README.TXT, the LICENCE.TXT, the air file, and a sample virtual host entry from httpd.conf using mod_rewrite, you should download MyUrlShortner.zip.

Smith Project - Open Source Coldfusion Server

2007-05-08T06:14:15-07:00

The Smith Project, another alternative CFML server, announced yesterday that they've gone to an open source license.

From their web site:

07-May-2007

Smith goes open-source.

After the very positive feedback from the ColdFusion® Developer Community, youngculture decided to open source its ColdFusion® Server "Smith". Till the end of April Smith Application Server has been downloaded more than 6'000 times.

Developers are welcome to join the project. The project is published under the GPL Licence and will be run and maintained by the newly founded Smith Open Source Software Association (SOSSA).

I haven't tried Smith yet, but it looks promising.

Paging Through Record Sets without URL variables

2007-04-06T17:41:01-07:00

One of my clients recently asked me to avoid the use of URL variables when paging through record sets. He wanted the "clean" URL look. So I converted some code I'd written to the following.

The following code uses a hidden form and some javascript to achieve the first/next/previous/last functionality. It also displays "Showing records X - Y of Z total records"

<cfsetting enablecfoutputonly="yes">
<cfset perPage = 100>

<cfparam name="session.lastStartRow" default="1">
<cfparam name="startRow" default="#session.lastStartRow#">
<cfif startRow gt qry.recordCount or startrow lt 1>
     <cfset startRow = 1>
</cfif>

<cfset nextStartRow = startRow + perPage>
<cfset prevStartRow = startRow - perPage>

<cfset endRow = startRow + perPage - 1>
<cfif endRow gt qry.recordCount>
     <cfset endRow = qry.recordCount>
</cfif>

<cfset session.lastStartRow = startRow>

<cfset lastPageStart = qry.recordCount - (qry.recordCount MOD perPage)>

<cfoutput><form name="frmPage" action="DataTable.cfm" method="post">
<input type="hidden" name="startRow" value="1" id="startRow">
</form>
<script language="Javascript">
function goPage(startRow) {
     // update the form and submit
     document.frmPage.startRow.value = startRow;
     document.frmPage.submit();
}
</script>
</cfoutput>

<cfsavecontent variable="pager"><cfoutput>
<p>
Showing records #startRow#-#endRow# of #qry.recordCount#.
<br/>
<a href="javascript:goPage(1);">First</a>  
<cfif startRow gt 1><a href="javascript:goPage(#prevStartRow#);">Previous</a><cfelse>Previous</cfif>  
<cfif endRow lt qry.recordCount><a href="javascript:goPage(#nextStartRow#);">Next</a><cfelse>Next</cfif>  
<a href="javascript:goPage(#lastPageStart#)">Last</a>
</p></cfoutput></cfsavecontent>
<cfsetting enablecfoutputonly="yes">

<cfoutput>#pager#</cfoutput>

<cfoutput>#pager#</cfoutput>

Join the Open Source NCAA Pool!

2007-03-12T16:34:52-07:00

The Open Source NCAA Pool is now open! The winner gets a 2gb USB Flash Drive!

http://www.opensourcecf.com/forums/ncaapool.cfm

CFMBB 1.20 Release Candidate Available

2007-03-07T10:16:40-07:00

Project Page for CFMBB: http://www.cfmbb.org/

I've been working on CFMBB 1.20 for a little over a month now, adding features, debugging, etc... there are a HUGE number of changes to CFMBB 1.20. User groups, restricted forums based on usergroup membership, integrated "content management", integrated file manager, integrated chat, lots of caching for better performance on busy sites, improved installation script, CAPTCHA for improved spam prevention, new topic notification options for entire site, per conference, and per forum, along with some bug fixes, modifications for Bluedragon 7 compatibility, etc.

Download CFMBB 1.20RC now!

Thanks to everyone who helped me get it to this point! And thanks to Ray for a great app to start with :)

ImageCFC 2.14 Released

2007-03-07T09:53:08-07:00

Project Page for ImageCFC: http://www.opensourcecf.com/imagecfc/

New in Version 2.14 - Exact Size Thumbnails

Thanks to some contributed code, there is now a new "cropToExact" argument to the resize() method. This argument, when combined with a specified width, specified height, and the preserveAspect argument being set to true will cause a image to be resized then cropped to fit exactly within the specified dimensions.

For example, this will allow you to take a 800x600 image, and create a 100x100 thumbnail while still preservign the aspect ratio. In this case, the image would be resized to 133x100, then cropped to 100x100.

Download ImageCFC 2.14 Now!

CFMBB 1.20 In Beta

2007-02-27T01:24:20-07:00

CFMBB 1.20 is in beta now! It includes many new features, including support for user groups, restricting forum access to specific user groups, integration of the CFOpenChat chat software, addition of basic content management features with integrated file manager (CFFM).

Themes have been "simplified" in that the navigation is no longer included in the header/footer pages. Previous versions of the themes included with CFMBB used wrapping tables, which aren't used any more.

Version 1.20 also includes several bug fixes, adds support for Bluedragon 7 (they've implemented a new built-in CFML function called querySort, which was the name of one of the UDFs in CFMBB, so I had to change its name to qrySort)

This is not an official release, but if you'd like to download the beta for testing, it's here.

Check out the demo here. Username: admin, password: admin

Open Source NCAA Tournament Pool

2007-02-27T01:16:13-07:00

My NCAA Tournament pool application has been updated. It now works with both Galleon (untested) and CFMBB. You can probably pretty easily modify it to work with pretty much any authentication framework.

For a demo, check out http://www.opensourcecf.com/forums/ncaapool.cfm

The project page is here: www.opensourcecf.com/ncaapool

The brackets included are current projections from CollegeRPI.com (Jerry's February 23 brackets). Don't come whining to me about why your team isn't in there, and don't come whining to me about why your team is seeded so low!

Determining Zip Code Proximity

2007-02-06T12:51:00-07:00

So I got a request from one of our development officers the other day. They wanted to be able to perform prospect reports based on zip code, or a range of zip codes. So I started investigating, and found numerous resources thanks to the members of the coldfusion community on the cf-talk mailing list.

First, someone pointed me to http://www.teamredline.com/, a company that sells zip code databases for $5. The database contains city, state, state abbreviation, zip code, latitude, and longitude. I forked out the $5 and downloaded the data, and then imported it into SQL Server.

Russ also provided a SQL Server function that would determine the distance between two points on the globe, and here it is:

CREATE FUNCTION [dbo].[getDistance]
(
@lat1 numeric(9,6),
@lon1 numeric(9,6),
@lat2 numeric(9,6),
@lon2 numeric(9,6)
)
RETURNS NUMERIC( 10, 5 )
AS
BEGIN
DECLARE @x decimal(20,10)
DECLARE @pi decimal(21,20)
SET @pi = 3.14159265358979323846
SET @x = sin( @lat1 * @pi/180 ) * sin( @lat2 * @pi/180 ) + cos(
@lat1 *@pi/180 ) * cos( @lat2 * @pi/180 ) * cos( abs( (@lon2 * @pi/180) -
(@lon1 *@pi/180) ) )
SET @x = atan( ( sqrt( 1- power( @x, 2 ) ) ) / @x )
RETURN ( 1.852 * 60.0 * ((@x/@pi)*180) ) / 1.609344
END

He also provided a method of querying based on zip code that used a cross join. Several other users had recommended modifying his query to restrict the number of zip codes it compares by looking for latitude between A-X and A+X where A is the latitude of the origin zip code, and X is some factor of degrees that would contain the search radius. You can do the same for longitude (though the further north you go, the wider the area you end up including because the longitude is only 69 degrees per mile at the equator... but enough math! Here's the query, cfquery style:

SELECT
z2.CITY, z2.ABBR, z2.ZIPCODE
FROM
ADSPRD.dbo.zipcodes z
cross join ADSPRD.dbo.zipcodes z2
WHERE
z.zipCode=<cfqueryparam cfsqltype="cf_sql_char" value="#zipcode#">
AND z2.LATITUDE BETWEEN z.latitude-(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*0.014457*2) and z.latitude+(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*0.014457*2)
AND z2.LONGITUDE BETWEEN z.longitude-(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*0.014457*2) and z.longitude+(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*0.014457*2)
and ADSPRD.dbo.getDistance(z.Latitude, z.longitude,z2.latitude, z2.longitude)
<= <cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">;

But I found an even faster way, as follows. It uses some Transact-SQL statements, but gets the same results without the cross join.

DECLARE @lat1 decimal(5,2);
DECLARE @long1 decimal(5,2);
DECLARE @rangeFactor decimal(7,6);
SET @rangeFactor = 0.014457;
SELECT @lat1 = LATITUDE, @long1 = LONGITUDE from ADSPRD.dbo.zipcodes where zipcode = <cfqueryparam cfsqltype="cf_sql_char" value="#zipcode#">;

SELECT B.CITY, B.ABBR, B.zipcode
FROM ADSPRD.dbo.zipcodes B
WHERE
B.LATITUDE BETWEEN @lat1-(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*@rangeFactor) and @lat1+(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*@rangeFactor)
AND B.LONGITUDE BETWEEN @long1-(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*@rangeFactor) and @long1+(<cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">*@rangeFactor)
AND ADSPRD.dbo.getDistance(@lat1,@long1,B.latitude,B.longitude)
<= <cfqueryparam cfsqltype="cf_sql_smallint" value="#range#">;

The difference in query execution time is pretty minimal in terms of actual milliseconds, but it is significant, anywhere from 2x to 3x faster, depending on the radius of the area you're looking in.

UPDATE - Mysql GetDistance Function

goondocs.com took the above code and produced a MySQL function for the same purpose. Since links in comments in my blog don't do anything for search engine visibility due to the nofollow attribute, I'm posting the link up here as an update:

MySQL function to compute the distance between two zip codes

CFCPhotoBlog to use ImageCFC

2007-01-29T09:47:36-07:00

I had a conversation with Seth Duffey via email the other day. Seth is the author of CFCPhotoBlog, a free, open source photo blogging project. It's a pretty nice project, if you're looking for a photo blogging application.

Looks like future versions are going to implement my ImageCFC project for some basic image manipulation like flip and rotate.

Check it out if you get a chance!

CFOpenChat 1.01 Released

2007-01-26T11:21:00-07:00

CFOpenChat version 1.01 is now available. There were two very minor bug fixes, both of which were discussed in the forums quite some time ago, I finally decided to put out a release.

download CFOpenChat 1.01 here.

ImageCFC 2.13 Now Available

2007-01-25T12:37:43-07:00

ImageCFC version 2.13 is now available. Very minor bug fix only to prevent unfriendly errors when attempting to read non-image files or unsupported image types like CMYK jpeg images.

download ImageCFC 2.13 here.

ImageCFC 2.11 Released

2006-12-18T13:33:56-07:00

Project Page for ImageCFC: http://www.opensourcecf.com/imagecfc/

version 2.11 includes the following changes:

performance improvements to the GaussianFilter.cfc and BoxBlurFilter.cfc
corrected bugs in GetOption() method
Added an object oriented wrapper cfc called ImageObject.cfc (as yet undocumented, though the cfc itself has some example code)
corrected documentation error in docs/getOption.cfm

I originally realized 2.11 on December 14, but made a minor correction to ImageObject.cfc today and repacked it without changing the version number so if you downloaded version 2.11 already, please do so again.

Also, ImageCFC 2.11 has been integrated into CFFM 1.15.

UDF to generate File Drops in CSV, Excel, and Tab delimited formats

2006-12-18T09:41:46-07:00

At a reader's request, I'm posting a UDF I wrote to generate file drops from queries. The UDF takes as its arguments a query, a format (EXCEL, CSV, or TAB), a list of column names, and a list of column labels. It returns a text string that can be used to either generate a file on the server or can be returned with cfcontent with the appropriate mime type.

<cfscript>
function formatFileOutput(qry, format, columnNames, columnLabels)
{
  // use java string buffer to dramatically improve
  // performance for large queries.
  var output = createObject("java","java.lang.StringBuffer");
  var x = 1;
  var fields = "";
  var row = 1;
  var col = 1;

  var PAGE_HEADER = "";
  var PAGE_FOOTER = "";
  var ROW_HEADER = "";
  var ROW_FOOTER = "";
  var START_OUTPUT = "";
  var END_OUTPUT = "";
  var START_ROW = "";
  var END_ROW = "";
  var START_FIELD = "";
  var END_FIELD = "";

  // generate column label structure
  for (x=1; x lte listLen(columnLabels); x = x + 1)
  {
   columnData[listGetAt(columnNames,x)] = listGetAt(columnLabels,x);
  }

  format = trim(ucase(format));

  // set up output variables
  if (format eq "CSV" or format eq "TAB")
  {
   page_header = "";
   row_header = "";
   for (x=1; x lte listLen(columnNames); x = x + 1)
   {
    row_header = listAppend(row_header, columnData[listGetAt(columnNames,x)]);
   }
   row_header = row_header & chr(13) & chr(10);
   start_output = "";
   end_output = "";
   start_row = "";
   end_row = chr(13) & chr(10);
   start_field = "";
   if (format eq "TAB") {
    row_header = listChangeDelims(row_header," ");
    end_field = " ";
   } else {
    end_field = ",";
   }
   page_footer = "";
  } else if (format eq "EXCEL") {
   page_header = "<HTML;
<head>
<title>Results</title>
<style type=""text/css"">
BODY, TD {
font-family: sans-serif;
white-space: nowrap;
}
TD.header {
font-weight: bold;
background-color: ffff00;
}
</style>
</head>
<body>";
   row_header = "<tr>#Chr(10)#";
   for (x=1; x lte listLen(columnNames); x = x + 1)
   {
    row_header = row_header & " <td class=#chr(34)#header#chr(34)#>#columnData[listGetAt(columnNames,x)]#</td>#CHR(10)#";
   }
   row_header = row_header & "</tr>#Chr(10)#";

   start_output = "<table cellpadding=2 cellspacing=0 border=1>#Chr(10)#";
   end_output = "</table>#Chr(10)#";
   start_row = "<tr>#Chr(10)#";
   end_row = "</tr>#Chr(10)#";
   start_field = " <td valign=top>";
   end_field = "</td>#Chr(10)#";
   page_footer = "</body></html>";
  }
  output.append(PAGE_HEADER);
  output.append(START_OUTPUT);
  output.append(ROW_HEADER);
  for (row=1; row lte qry.recordCount; row = row + 1)
  {
   output.append(START_ROW);
   for (col = 1; col lte listLen(columnNames); col=col+1)
   {
    thisColumn = listGetAt(columnNames,col);
    field = evaluate("qry.#ThisColumn#[row]");
    if (field eq "" and format eq "EXCEL") {
     field=" ";
    }
    output.append(START_FIELD);

    if (format eq "CSV")
    {
     if (field neq "" and not isNumeric(field) )
     {
      field = replace(field,chr(34),"#chr(34)##chr(34)#","ALL");
      field = "#Chr(34)##field##Chr(34)#";
     }
     output.append(field);
    } else {
     output.append(FIELD);
    }
    if (col lt listlen(columnNames,", ")) {
     output.append(END_FIELD);
    }
   }
   output.append(END_ROW);
  }
  output.append(END_OUTPUT);
  output.append(PAGE_FOOTER);
  return output.toString();
}
</cfscript>

Here's an example of how to use it. You could place the following code in a file called "drop.cfm"

<cfparam name="FORMAT" default="TAB">
<cfquery name="myQuery" datasource="WEBREPORTS_MSSQL">
select top 30 * from dbo.TB907
</cfquery>
<cfscript>
if (format eq "EXCEL")
{
  mimetype = "application/msexcel";
  filename = "report.xls";
} else {
  mimetype = "text/plain";
  filename = "report.txt";
}
results = formatFileOutput(myQuery, format, myQuery.columnlist, myQuery.columnlist);
</cfscript>
<cfsetting enablecfoutputonly="Yes">
<cfcontent type="#mimetype#" reset="Yes">
<cfheader name="Content-Disposition" value="attachment; filename=#filename#">
<cfoutput>#results#</cfoutput>

ImageCFC 2.10 Released

2006-12-13T16:10:25-07:00

Project Page for ImageCFC: http://www.opensourcecf.com/imagecfc/

version 2.10 adds image filtering capability to ImageCFC, including the following:

o simple blur (very fast)
o box blur (slow)
o gaussian blur (slow)
o sharpen
o posterize

Some examples of each of the filters.

http://www.opensourcecf.com/imagecfc/examples.cfm

Thanks to everyone who assisted via the list!

Rick

ImageCFC 2.0 Released

2006-12-08T23:36:44-07:00

I've completed imageCFC version 2.0

Numerous changes since beta 3... and unfortunately some of the changes will break your code if you're using image.cfc 2.0 beta.

http://www.opensourcecf.com/imagecfc

NEW (REAL) DOCUMENTATION!
http://www.opensourcecf.com/imagecfc/docs/imageCFC.cfm

This release includes a few bug changes plus the following changes:

readImage() and writeImage() are now public methods.
writeImage() method writes to temp directory and then uses cffile to move image to its final destination. This corrects a known issue where resizing an image down and saving it to the same file did not actually reduce the physical file size.
changed scaleX() to scaleWidth()
changed scaleY() to scaleHeight()
Added optional preserveAspect argument to resize() method (allowing you to resize an image to fit within a certain width and height without messing with the aspect ratio)
You can turn text antialiasing on and off, or change the interpolation mode now using the setOption() method.
WROTE REAL API DOCUMENTATION!

There are a variety of other fixes and minor enhancements. Please see the full change log on the site for details.

ImapCFC Update

2006-12-06T15:50:30-07:00

CFOpenMail / ImapCFC project page

Every time I made a change to the code in imap.cfc, I had to reinitialize it and log in again. I had to do this because the init() method stored the connection information in the variables scope of the CFC.. so reloading the CFC would wipe them out. That got old really fast, so I moved the connection information into the session scope. Now during development, the CFC can be reloaded on every page call if I want.. but I'll probably just add a "refresh CFC" shortcut into CFOpenMail to ccause that to occur so it only happens when I want it to.

I updated the delete() method to allow the deletion of multiple messages. I also adjusted the getfolderinfo() and getfolderstructure() methods so they return more information, and don't attempt to get information like message counts and unread message counts on folders that can't actually hold messages.

The copyMessages() method now throws meaningful errors for things like "The destination folder does not exist" and "The destination folder cannot contain messages".

Also, the getMessage() method will throw a meaningful message when you attempt to retrieve an invalid message number. "The specified message number was not found in the specified folder." instead of what was essentially an "Array index out of bounds" error.

ImapCFC Update

2006-12-05T16:02:47-07:00

CFOpenMail / ImapCFC project page

I corrected the issue with the folderDelete() method. It's very strange the way the actual delete method works in the java folder object. It nearly always returns true, even if the delete fails. The correct way to determine if the delete was successful is to run the exists() method on the folder you just deleted. Sometimes, I think OO programming is a little wacky. Or maybe it's just this particular implementation.

I also implemented the copyMessages() method in CFOpenMail. I haven't tested it thorougly, but it does work.

The CFC on the project page has been updated to include today's changes.

ImapCFC Update

2006-12-04T15:58:27-07:00

CFOpenMail / ImapCFC project page

I corrected a bug in the folderRename() method involving mismatched variable names (obj_Folder and objFolder). However, the method still doesn't work. Maybe my imap server doesn't allow renaming of folders. It says it's working, but it's just not renaming the folder. No errors, and it returns true.

I also added a recurse option to the folderDelete() method that should prevent you from deleting a non-empty folder unless you specify to do the delete recursively. This too, doesn't work. Might be time to drop a line to the JavaMail-INTEREST mailing list.

Imap.CFC Update

2006-12-01T22:36:16-07:00

CFOpenMail / ImapCFC project page

Earlier this week, I decided it would be fun to build a webmail application. Of course, any good webmail application connects to an IMAP mail server, so I needed to figure out how to use imap in Coldfusion.

Although Bluedragon has a CFIMAP tag, Coldfusion (currently) does not. I wanted to go open source, and didn't want to require any DLL installations or anything so most of the custom tag options out there were not options (like CFX_IMAP, CFX_IMAP4, etc). But I did find a project on sourceforge called cfimap-cfc. Sweet.

I started cranking away, and I've made a LOT of changes to imap.cfc, enhancing its functionality, fixing bugs, etc. Some of the major changes so far:

an authenticated imap session can be stored in memory (the session scope), so you don't have to authenticate every time you try to do something. This was a HUGE performance increase.
the "view" method was incompatible with multipart mime messages with parts whose content type was multipart/*. In otherwise, a message might have two parts, but one of those parts might also have multiple parts as well. Curiously, the old imap.cfc worked with such messages but only grabbed the first subpart in such situations. This required taking part of the view() method out and putting it into a separate method called getParts(), which calls itself recursively for multipart parts.
I've properly var scoped *EVERYTHING*. Version 1.0 of imap.cfc was not var scoped at all, and you could have easily experienced all kinds of variable problems.
The old imap.cfc attempted to put HTML and text attachments inline. Personally, in a web based application, I'd just rather see them as attachments, and so that's what it does now.
The download method was enhanced by adding an includeData argument, which, when false, causes the returned structure to not include the actual binary file contents. The method also now returns file size as well, so you can publish the list of attachments along with their content type and size.
Added a slew of try/catch statements because some folders can't contain messages, so you can't open them. I don't really know why for sure, but I've got one such folder in my Sent folder, so I added error trapping.
I also added code hints, changed some variable names and column names, and did some commenting of the code too.

It's worth mentioning that I've never worked with the JavaMail API before, so this was fun and challenging.

There's still a lot of work to do, particularly with regards to the send() feature. I also haven't yet tested the deleting, creating, or renaming of folders, nor have I tested the copyMessages() method either.

Using coldfusion to strip some or all HTML tags from a string

2006-11-28T15:45:00-07:00

Years ago (ie, 1999), I wrote a custom tag called CF_TAGSTRIPPER that would strip HTML tags from a source string, optionally preserving specific tags.

A few years ago, I converted it to a UDF and I've used it in a variety of my applications to strip out all but a few tags - like if I wanted to allow users to use bold and italic tags.

Recently, I've had a desire to strip out only certain tags, so I modified my tagStripper function to perform this task as well. Here's the code. Please let me know if you see anything wrong with it!

There are two versions of this UDF - one for CFMX and one for CF 5. They are functionally the same, so use whichever you prefer.

CFMX Version using CFFUNCTION tag:

<cffunction name="tagStripper" access="public" output="no" returntype="string">
    <cfargument name="source" required="YES" type="string">
    <cfargument name="action" required="No" type="string" default="strip">
    <cfargument name="tagList" required="no" type="string" default="">

<!---
    source = string variable
        This is the string to be modified

    action = "preserve" or "strip"
        This function will either strip all tags except
        those specified in the tagList argument, or it will
        preserve all tags except those in the taglist argument.
        The default action is "strip"

    tagList = string variable
        This argument contains a comma separated list of tags to be excluded from
        the action. If the action is "strip", then these tags won't be stripped.
        If the action os "preserve", then these tags won't be preserved (ie, only
        these tags will be stripped)

    EXAMPLE

    tagStripper(myString,"strip","b,i")

    This invocation will strip all html tags except for
    <b></b> and <i></i>
--->
    <cfscript>
    var str = arguments.source;
    var i = 1;

    if (trim(lcase(action)) eq "preserve")
    {
        // strip only the exclusions
        for (i=1;i lte listlen(arguments.tagList); i = i + 1)
        {
            tag = listGetAt(tagList,i);
            str = REReplaceNoCase(str,"</?#tag#.*?>","","ALL");
        }
    } else {
        // if there are exclusions, mark them with NOSTRIP
        if (tagList neq "")
        {
            for (i=1;i lte listlen(tagList); i = i + 1)
            {
                tag = listGetAt(tagList,i);
                str = REReplaceNoCase(str,"<(/?#tag#.*?)>","___TEMP___NOSTRIP___\1___TEMP___ENDNOSTRIP___","ALL");
            }
        }
        str = reReplaceNoCase(str,"</?[A-Z].*?>","","ALL");
        // convert excluded tags back to normal
        str = replace(str,"___TEMP___NOSTRIP___","<","ALL");
        str = replace(str,"___TEMP___ENDNOSTRIP___",">","ALL");
    }

    return str;
    </cfscript>
</cffunction>

Coldfusion 5 Compatible Version:

<cfscript>
function tagStripper(str)
{
    var i = 1;
    var action = 'strip';
    var tagList = '';

    if (ArrayLen(arguments) gt 1 and lcase(arguments[2]) eq 'preserve')
    {
        action = 'preserve';
    }
    if (ArrayLen(arguments) gt 2)
    {
        tagList = arguments[3];
    }

    if (trim(lcase(action)) eq "preserve")
    {
        // strip only those tags in the tagList argument
        for (i=1;i lte listlen(tagList); i = i + 1)
        {
            tag = listGetAt(tagList,i);
            str = REReplaceNoCase(str,"</?#tag#.*?>","","ALL");
        }
    } else {
        // strip all, except those in the tagList argument
        // if there are exclusions, mark them with NOSTRIP
        if (tagList neq "")
        {
            for (i=1;i lte listlen(tagList); i = i + 1)
            {
                tag = listGetAt(tagList,i);
                str = REReplaceNoCase(str,"<(/?#tag#.*?)>","___TEMP___NOSTRIP___\1___TEMP___ENDNOSTRIP___","ALL");
            }
        }
        // strip all remaining tsgs. This does NOT strip comments
        str = reReplaceNoCase(str,"</?[A-Z].*?>","","ALL");
        // convert unstripped back to normal
        str = replace(str,"___TEMP___NOSTRIP___","<","ALL");
        str = replace(str,"___TEMP___ENDNOSTRIP___",">","ALL");
    }

    return str;
}
</cfscript>

CFOpenChat Updated

2006-09-06T06:54:03-07:00

A lot of progress has been made in the last week with regards to the reliability of CFOpenChat. It handles temporary connection failures much better now, and will hopefully no longer just randomly decide to boot everyone out of the chat room at will.

CFOpenChat is a coldfusion powered chat room application built using Rob Gonda's ajaxCFC. It supports MSSQL and MySQL, and could easily be adapted for other database as well.

For full details, a demo, and the download, visit:

http://www.opensourcecf.com/cfopenchat/

CFOpenChat is free, open source software licensed under the BSD license.

Debugging ajaxCFC

2006-08-24T17:53:38-07:00

Rey Bango posted this to cf-talk,and I thouht wothy of blogging.

Here's a tip that I wanted to share within everyone here. It may be
known but I only found out about it today and wanted to share.
If you ever get the dreaded "Invalid Reply from Server" message from
AjaxCFC, spark up Firefox/FireBug and call your site from your local IP.
This will give you the actual message that DWR is sending back.

Put a stop point at about line 517 (or immediately after
"batch.req.send(query);") of engine.js and look for the "batch" object.
In the there you'll find the "req" (XMLHttpRequest request) object which
has a standard attribute called responseText. That will give you all of
the details of your error but for security reasons, it only shows it via
your local IP address (127.0.0.1).

Rey...

CFML String Concatenation is SLOW! Use Java StringBuffer instead

2006-08-18T07:38:45-07:00

I was trying to speed up a process of mine that involves a large amount of string concatenation.

In other words, <cfset str = str & someOtherString>

Turns out there's a much faster way. In my case, I was dynamically generating an data file from a query. Each row had let's say 50 fields. Generation of each row required 3 string concatenations at a time (maybe more, depending on how it worked when compiled to the servlet). Do a drop of 5000 records, and well, that's a lot of string concats! 750,000 at a minimum.

Someone on cf-talk suggested using a StringBuffer might be wise because Coldfusion probably creates a new string object every time you do <cfset foo = foo & foo2>. So I decided to write some code to test it out.

Sure enough, using the java StringBuffer class is quite a lot faster. On my local machine, I ran the following code (see below). The CFML method completed in 89 seconds, while the java StringBuffer method completed in only 28 seconds - about 1/3 of the time!

Here's the code, if you're interested:

<cfset a = "">
<cfset starttime = now()>
<cfset cnt = 0>
<cfloop index="i" from="1" to="2000000">
    <cfset a = a & "This is some crazy stuff. ">
    <cfset cnt = cnt + 26>
    <cfif i mod 1000 is 0>
        
        <cfset a = "">
    </cfif>
</cfloop>
<cfoutput><p>Done with #cnt# bytes in #abs(dateDiff('s',Now(),starttime))# seconds.</p></cfoutput>

<cfset a = createObject("java","java.lang.StringBuffer")>
<cfset starttime = now()>
<cfset cnt = 0>
<cfloop index="i" from="1" to="2000000">
    <cfset a.append("This is some crazy stuff. ")>
    <cfset cnt = cnt + 26>
    <cfif i mod 10000 is 0>
        
        <cfset a = createObject("java","java.lang.StringBuffer")>
    </cfif>
</cfloop>
<cfoutput><p>Done with #cnt# bytes in #abs(dateDiff('s',Now(),starttime))# seconds.</p></cfoutput>

Asynchronous HTTP from Coldfusion

2006-07-18T18:06:47-07:00

Ever wanted to make an HTTP request but you didn't really care whether or not it returned anything successfully?

You can't do that with CFHTTP... well, you can, but you would have to still wait for it to finish before your page continued - it's not asynchronous.

Well, your prayers are answered. Mark Mandel justed posted his AsyncHTTP package that uses existing java classes to perform asynchronous http GET and POST operations.

You can find out more here:

http://www.compoundtheory.com/?action=asynchttp.index

Reading large files with java versus CFFILE

2006-07-12T14:15:39-07:00

A question was posted on the cf-talk list (thread) about reading large files with CFFILE and problems they were having.

I suggested trying java to read the large file line by line and I posted the following code:

<cfsetting showdebugoutput="Yes">
<cfscript>
cnt = 0;
// large text file, 4MB, 80,000+ lines
srcFile = "E:\Inetpub\wwwroot\tools\mass_email\list.dat";
// create a FileReader object
fr = createObject("java","java.io.FileReader");
// Call the constructure with the source file path
fr.init(srcFile);
// create a BufferedReader object
br = createObject("java","java.io.BufferedReader");
// call the constructor with the FileReader as the arg
br.init(fr);
// read the first line
str = br.readLine();
// loop ... str will be undefined if there are no more lines
while (isDefined("str")) {
  // do stuff with the string
  cnt = cnt + 1;
  // read the next line so we can continue the loop
  str = br.readLine();
}
// close the buffered reader object
br.close();
writeOutput(cnt);
</cfscript>

The code above was tested on CFMX 7 and it does work. On my server, it consistently returns the results in about 400ms (ranging between 350ms and 500ms).

In order to compare, I wrote some CFML code that does essentially the same thing using CFFILE and looping through the file content as a list with chr(10) as the delimiter.

The CFFILE route was slower and much more erratic, ranging from 450ms to over 2000ms - probably averaging 1400ms in the 20-30 times I reloaded the page.

So if you're reading a large file and doing line by line processing - consider using native java rather than CFFILE.

BlogCFM 1.12 Released

2006-06-09T19:49:00-07:00

I finally got around to fixing all the bugs in BlogCFM and made version 1.12 available for download from the BlogCFM web site at http://www.blogcfm.org/download.cfm

It is purely a bug fix release, and hopefully will be nice and stable!