<!--- get the server ID for the specific web site
    from IIS.  The default web site is usually "1"
    --->
<cfset serverid="2017647531">

    <!---
        //  metabasePath is of the form "IIS://<servername>/<service>/<siteID>/Root[/<vdir>]"
        //    for example "IIS://localhost/W3SVC/1/Root"
    --->
<cfset metabasePath = "IIS://localhost/W3SVC/#serverid#/Root">

<!--- name of the virtual directory --->
<cfset vdirName = "vdir001">

<!--- physical path for this virtual directory --->
<cfset physicalPath = "D:\Inetpub\ricktest\realdir">

<!--- full path to the System.DirectoryServices.dll --->
<cfset dllPath = "C:\WINDOWS\Microsoft.NET\Framework\v1.1.4322\System.DirectoryServices.dll">

<!--- instantiate a DirectoryEntry .NET object --->
<cfobject
    type=".net"
    class="System.DirectoryServices.DirectoryEntry"
    assembly="#dllPath#"
    name="site">

<!--- initialize the object with the metabase path --->   
<cfset site.init(metabasePath)>

<!--- you need the classname for later --->
<cfset className = site.Get_SchemaClassName()>

<cfif reFind("VirtualDir$",className) gt 0>
    <!--- Get the children so we can add a new child --->
    <cfset vdirs = site.Get_Children()>
    <cftry>
        <!--- add the new virtual directory --->
        <cfset newVDir = vdirs.Add(vDirName, className)>
        <cfcatch type="any">
            <cfoutput><h3>Failed to create #vDirName#</h3></cfoutput>
            <cfif cfcatch.ToString() contains "already exists">
                <p>Another directory with that name already exists.</p>
            <cfelse>
                <cfoutput><p>#cfcatch.ToString()#</p></cfoutput>
            </cfif>
            <cfabort>
        </cfcatch>
    </cftry>
    <Cftry>
        <!--- set the PAth property to the physical directory path --->
        <cfset newVDir.Get_Properties().Get_Item("Path").Set_Value(physicalPath)>
        <!--- commit the changes --->
        <cfset newVDir.CommitChanges()>

        <cfcatch type="any">
            <cfdump var="#cfcatch.ToString()#">
            <cfdump var="#cfcatch#">
            <Cfabort>
        </cfcatch>
    </cftry>
</cfif>

<cfsetting enablecfoutputonly="yes">
<cfset perPage = 100>
<!--- set defaults --->
<cfparam name="session.lastStartRow" default="1">
<cfparam name="startRow" default="#session.lastStartRow#">
<cfif startRow gt qry.recordCount or startrow lt 1>
     <cfset startRow = 1>
</cfif>
<!--- calculate next and previous starting position --->
<cfset nextStartRow = startRow + perPage>
<cfset prevStartRow = startRow - perPage>
<!--- calc the last row for display purposes --->
<cfset endRow = startRow + perPage - 1>
<cfif endRow gt qry.recordCount>
     <cfset endRow = qry.recordCount>
</cfif>
<!--- save in case we leave the page and come back --->
<cfset session.lastStartRow = startRow>
<!--- the index of the first row of the LAST page is lastPageStart --->
<cfset lastPageStart = qry.recordCount - (qry.recordCount MOD perPage)>
<!--- output the hidden form used for navigation --->
<cfoutput><form name="frmPage" action="DataTable.cfm" method="post">
<input type="hidden" name="startRow" value="1" id="startRow">
</form>
<script language="Javascript">
function goPage(startRow) {
     // update the form and submit
     document.frmPage.startRow.value = startRow;
     document.frmPage.submit();
}
</script>
</cfoutput>

<!---
     Save the navigation to a variable so we can
     output it above AND Below the content easily.
--->
<cfsavecontent variable="pager"><cfoutput>
<p>
Showing records #startRow#-#endRow# of #qry.recordCount#.
<br/>
<a href="javascript:goPage(1);">First</a> &nbsp;
<cfif startRow gt 1><a href="javascript:goPage(#prevStartRow#);">Previous</a><cfelse>Previous</cfif> &nbsp;
<cfif endRow lt qry.recordCount><a href="javascript:goPage(#nextStartRow#);">Next</a><cfelse>Next</cfif> &nbsp;
<a href="javascript:goPage(#lastPageStart#)">Last</a>
</p></cfoutput></cfsavecontent>
<cfsetting enablecfoutputonly="yes">